应用笔记 · 2014年8月31日

TMS320F28335的存储器结构及如何在外扩RAM上调试程序

MS320F28335为哈佛结构的DSP,在逻辑上有4M×16位的程序空间和4M×16位点的数据空间,但在物理上已将程序空间和数据空间统一成一个4M×16位的空间。TMS320F28335片上有256K×16位的FLASH,34K×16位的SRAM,8K×16位的BOOT ROM,2K×16位的OPT ROM。

1、 TMS320F28335片上SARAM

TMS320F28335片内共有34K×16位单周期单次访问随机存储器的SARAM,分成10个块,他们分别称为M0、M1、L0-L7。

 

MO和M1块SARAM的大小均为1K×16位,当复位后,堆栈指针指向M1块的起始地址,堆栈指针向上生长。M0和M1段都可以映射到程序区和数据区。

 

L0-L7块SARAM的大小均为4K×16位,既可映射到程序空间,也可映射到数据空间,其中L0-L3可映射到两块不同的地址空间并且受片上的FLASH中的密码保护,以免存在上面的程序或数据,被他人非法拷贝。

2、 TMS320F28335片上FLASH和OTP

TMS320F28335片上有256K×16位嵌入式FLASH存储器和1K×16位一次可编程EEPROM存储器,他们均受片上FLASH中的密码保护。FLASH存储器由8个32K×16位扇区组成,用户可以对其中任何一个扇区进行擦除、编程和校验,而其他扇区不变。但是,不能在其中一个扇区上执行程序来擦除和编程其他的扇区。

 

3、 TMS320F28335外部存储器接口

TMS320F28335的外部存储器接口包括:20位地址线,16(最大32)位数据线,3个片选控制线及读写控制线。这3个片选线映射到3个存储区域,Zone0,Zone6和Zone7。这3个存储器可分别设置不同的等待周期。

Zone0  存储区域:    0X004000—0X004FFF, 4K×16位   可编程最少一个等待周期

Zone6  存储区域:    0X100000—0X1FFFFF, 1M×16位  10ns   最少一个等待周期

Zone7  存储区域:    0X200000—0X2FFFFF, 1M×16位  70ns   最少一个等待周期

以下是我写的一个RAM仿真的CMD文件,已经调试通过了,硬件设计的外扩的RAM为Zone6空间,存储区域:0X100000—0X1FFFFF。
MEMORY
{
PAGE 0 :
/* BEGIN is used for the “boot to SARAM” bootloader mode      */
/* BOOT_RSVD is used by the boot ROM for stack.               */
/* This section is only reserved to keep the BOOT ROM from    */
/* corrupting this area during the debug process              */

BEGIN      : origin = 0x000000, length = 0x000002     /* Boot to M0 will go here                      */
BOOT_RSVD  : origin = 0x000002, length = 0x00004E     /* Part of M0, BOOT rom will use this for stack */
RAMM0      : origin = 0x000050, length = 0x0003B0

RAML0      : origin = 0x008000, length = 0x001000
RAML1      : origin = 0x009000, length = 0x001000
RAML2      : origin = 0x00A000, length = 0x001000
RAML3      : origin = 0x00B000, length = 0x001000

CSM_RSVD   : origin = 0x33FF80, length = 0x000076     /* Part of FLASHA.  Program with all 0x0000 when CSM is in use. */
CSM_PWL    : origin = 0x33FFF8, length = 0x000008     /* Part of FLASHA.  CSM password locations in FLASHA            */
ADC_CAL    : origin = 0x380080, length = 0x000009
RESET      : origin = 0x3FFFC0, length = 0x000002
IQTABLES   : origin = 0x3FE000, length = 0x000b50
IQTABLES2  : origin = 0x3FEB50, length = 0x00008c
FPUTABLES  : origin = 0x3FEBDC, length = 0x0006A0
BOOTROM    : origin = 0x3FF27C, length = 0x000D44
ZONE6      : origin = 0x100000, length = 0x040000     /* XINTF zone 6 – data space */

PAGE 1 :
RAMM1      : origin = 0x000400, length = 0x000400     /* on-chip RAM block M1 */
RAML      : origin = 0x00C000, length = 0x004000

ZONE6     : origin = 0x140000, length = 0x040000     /* XINTF zone 6 – data space */

}

SECTIONS
{
/* Setup for “boot to SARAM” mode:
The codestart section (found in DSP28_CodeStartBranch.asm)
re-directs execution to the start of user code.  */
codestart        : > BEGIN,     PAGE = 0
ramfuncs         : > RAML0,     PAGE = 0
.text            : > ZONE6,     PAGE = 0
.cinit           : > RAML0,     PAGE = 0
.pinit           : > RAML0,     PAGE = 0
.switch          : > RAML0,     PAGE = 0

.stack           : > RAML,     PAGE = 1
.ebss            : > RAML,     PAGE = 1
.econst          : > ZONE6,     PAGE = 1
.esysmem         : > RAML,     PAGE = 1

IQmath           : > RAML1,     PAGE = 0
IQmathTables     : > IQTABLES,  PAGE = 0, TYPE = NOLOAD
IQmathTables2    : > IQTABLES2, PAGE = 0, TYPE = NOLOAD
FPUmathTables    : > FPUTABLES, PAGE = 0, TYPE = NOLOAD

.reset           : > RESET,     PAGE = 0, TYPE = DSECT /* not used                    */
csm_rsvd         : > CSM_RSVD   PAGE = 0, TYPE = DSECT /* not used for SARAM examples */
csmpasswds       : > CSM_PWL    PAGE = 0, TYPE = DSECT /* not used for SARAM examples */

}

为了使调试开始时自动初始化XINTF以访问外扩RAM,还需要以下步骤,感谢TI社区Jay

打开C:\ti\ccsv6\ccs_base\emulation\gel\f28335.gel,找到里面的OnReset(int nErrorCode)函数。

6675.QQ_2A62FE56_20140717141902

把最后一行去掉注释。

你在连上CPU后,做一个Reset(Debug->Reset CPU)就会调用这个函数,从而可以使XINTF被使能。

这样之后,再去Load你的.out试试。

另外,请检查一下,你的Target Configuration文件.ccxml里面是否有包含这个gel。打开.ccxml,在Advanced标签下可以看到。

2677.QQ_2A62FE56_20140717142222

下图为存储空间地址分配。
b_large_1pBu_5a8c0000f07f5c15